// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target,buythings;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;

	if(get_flag(12,1) > 0){
		reset_dialog();
		add_dialog_str(0,"Magos is still here, ready to do business with you.",0);
		add_dialog_choice(0,"Leave.");
		add_dialog_choice(1,"Buy mage spells.");
		add_dialog_choice(2,"Buy priest spells.");
		buythings = run_dialog(0);
		if(buythings == 1){
			end();
		}
		if(buythings == 2){
begin_shop_mode("Magos' Incantations","Magos is the tribe's up-and-coming Wiseman.  His skill is self-apparent, and fortunately, he's willing to share for a reasonable price.",7,1,-1);
		}
		if(buythings == 3){
begin_shop_mode("Magos' Incantations","Magos is the tribe's up-and-coming Wiseman.  His skill is self-apparent, and fortunately, he's willing to share for a reasonable price.",8,1,-1);
		}
	}
	if(get_flag(12,1) == 0){
		set_flag(12,1,1);
		reset_dialog();
		add_dialog_str(0,"Magos is the village's Wiseman.  He is likely to replace Barbarus whenever he dies.  For his age, Magos is remarkably apt with his abilities.",0);
		if(party_size() > 1){
			add_dialog_str(1,"_Spirits be with you, Speres!_",0);
		}
		else{
			add_dialog_str(1,"_Spirits be with you, Spere!_",0);
		}
		add_dialog_str(2,"_I have heard about your troubles from the spirits who flow throughout me.  You are truly on a holy mission._",0);
		add_dialog_str(3,"_I can teach you how to let the spirits flow through you to empower yourself and diminish your enemies for a modest donation, if you need my assistance._",0);
		add_dialog_choice(0,"Leave.");
		add_dialog_choice(1,"Buy mage spells.");
		add_dialog_choice(2,"Buy priest spells.");
		buythings = run_dialog(0);
		if(buythings == 1){
			end();
		}
		if(buythings == 2){
begin_shop_mode("Magos' Incantations","Magos is the tribe's up-and-coming Wiseman.  His skill is self-apparent, and fortunately, he's willing to share for a reasonable price.",7,1,-1);
		}
		if(buythings == 3){
begin_shop_mode("Magos' Incantations","Magos is the tribe's up-and-coming Wiseman.  His skill is self-apparent, and fortunately, he's willing to share for a reasonable price.",8,1,-1);
		}
	}
break;